A Class of Models with the Potential to Represent Fundamental Physics
  1. Introduction
  2. Basic Form of Models
  3. Typical Behaviors
  4. Limiting Behavior and Emergent Geometry
  5. The Updating Process for String Substitution Systems
  6. The Updating Process in Our Models
  7. Equivalence and Computation in Our Models
  8. Potential Relation to Physics
  9. Additional Material
  10. References
  11. Index

3.8 Rules with Signature 2242

For 22 42, there are 40,405 inequivalent left-connected rules. Of these, about 36% stay connected when they evolve. Starting from two self-loops {{0,0},{0,0}}, and running for 8 steps, here is a sample of the 4000 or so distinct behaviors that are produced:

urules24 = Import["https://www.wolframcloud.com/obj/wolframphysics/Data/22-24-\ 2x0-unioned-summary.wxf"]; SeedRandom[6783]; GraphicsGrid[ Partition[ Take[Select[ ParallelMap[ UndirectedGraph[ Rule @@@ ResourceFunction["WolframModel"][#, {{0, 0}, {0, 0}}, 8, "FinalState"], GraphLayout -> "SpringElectricalEmbedding", VertexStyle -> ResourceFunction["WolframPhysicsProjectStyleData"][ "SpatialGraph", "VertexStyle"], EdgeStyle -> ResourceFunction["WolframPhysicsProjectStyleData"][ "SpatialGraph", "EdgeLineStyle"]] &, #Rule & /@ RandomSample[urules24, 300]], EdgeCount[#] > 10 && ConnectedGraphQ[#] &], 252], 14], ImageSize -> Full]

Most of these rules show the same kinds of behaviors we have seen before. But there is one major new kind of behavior that is observed: in a little less than 1% of all cases, the rules produce globular structures that in effect continually add various forms of cross-connections. Here are a few examples (notably, even though 22 42 rules can involve up to 7 distinct elements, these rules all involve just 4):

GraphicsGrid[ Partition[ ParallelMap[ Labeled[ResourceFunction["WolframModelPlot"][ ResourceFunction["WolframModel"][#[[1]], #[[2]], #[[3]], "FinalState"], ImageSize -> 1.1 {150, 100}], RulePlot[ResourceFunction["WolframModel"][#[[1]]], "RulePartsAspectRatio" -> 1, ImageSize -> Tiny]] &, {{{{1, 2}, {1, 3}} -> {{1, 2}, {1, 4}, {2, 4}, {4, 3}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {1, 3}} -> {{1, 4}, {1, 4}, {2, 4}, {3, 2}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {1, 3}} -> {{2, 2}, {2, 4}, {1, 4}, {3, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {1, 3}} -> {{2, 3}, {2, 4}, {3, 4}, {1, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {1, 3}} -> {{2, 3}, {2, 4}, {3, 4}, {4, 1}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {1, 3}} -> {{2, 4}, {2, 1}, {4, 1}, {4, 3}}, {{0, 0}, {0, 0}}, 9}, {{{1, 2}, {1, 3}} -> {{2, 4}, {2, 4}, {1, 4}, {3, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {1, 3}} -> {{2, 4}, {2, 4}, {2, 1}, {3, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {1, 3}} -> {{4, 1}, {1, 4}, {4, 2}, {4, 3}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {2, 3}} -> {{1, 2}, {2, 1}, {4, 1}, {4, 3}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {2, 3}} -> {{1, 3}, {1, 4}, {3, 4}, {3, 2}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {2, 3}} -> {{2, 3}, {2, 4}, {3, 4}, {1, 2}}, {{0, 0}, {0, 0}}, 9}, {{{1, 2}, {2, 3}} -> {{2, 4}, {2, 4}, {4, 1}, {4, 3}}, {{0, 0}, {0, 0}}, 9}, {{{1, 2}, {2, 3}} -> {{3, 2}, {2, 4}, {4, 3}, {3, 1}}, {{0, 0}, {0, 0}}, 9}, {{{1, 2}, {2, 3}} -> {{4, 1}, {4, 1}, {4, 3}, {2, 4}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {2, 3}} -> {{4, 2}, {2, 3}, {3, 4}, {1, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {2, 3}} -> {{4, 3}, {4, 3}, {1, 4}, {2, 3}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {3, 2}} -> {{2, 4}, {2, 4}, {4, 1}, {3, 4}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {3, 2}} -> {{4, 1}, {1, 2}, {2, 4}, {3, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {3, 2}} -> {{4, 1}, {1, 2}, {2, 4}, {4, 3}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {3, 2}} -> {{4, 1}, {4, 2}, {1, 2}, {3, 4}}, {{0, 0}, {0, 0}}, 12}, {{{1, 2}, {3, 2}} -> {{4, 1}, {4, 3}, {1, 3}, {4, 2}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {3, 2}} -> {{4, 2}, {2, 4}, {4, 1}, {3, 4}}, {{0, 0}, {0, 0}}, 10}, {{{1, 2}, {3, 2}} -> {{4, 2}, {4, 1}, {2, 1}, {4, 3}}, {{0, 0}, {0, 0}}, 9}}], 4], ImageSize -> Full, Alignment -> Bottom]

We will study these kinds of structures in more detail later. Note that the specific forms shown here depend on the underlying updating order usedthough for example random orders typically seem to give similar results. It is also the case that the detailed visual layout of graphs can affect the impression of these structures; we will address this in the next section when we discuss various forms of quantitative analysis.

It is remarkable how complex the structures are that can be created even from very simple rules. Here are three examples (with short codes wm5583, wm4519, wm2469) shown in more detail:

{{x, y}, {x, z}} -> {{y, z}, {y, w}, {z, w}, {w, x}}
RulePlot[ResourceFunction[ "WolframModel"][{{x, y}, {x, z}} -> {{y, z}, {y, w}, {z, w}, {w, x}}]]
ResourceFunction["WolframModelPlot"][#, ImageSize -> Tiny] & /@ ResourceFunction[ "WolframModel"][{{x, y}, {x, z}} -> {{y, z}, {y, w}, {z, w}, {w, x}}, {{0, 0}, {0, 0}}, 10, "StatesList"]
ResourceFunction[ "WolframModel"][{{x, y}, {x, z}} -> {{y, z}, {y, w}, {z, w}, {w, x}}, {{0, 0}, {0, 0}}, 16, "FinalStatePlot"]
{{x, y}, {y, z}} -> {{x, y}, {y, x}, {w, x}, {w, z}}
RulePlot[ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{x, y}, {y, x}, {w, x}, {w, z}}]]
ResourceFunction["WolframModelPlot"][#, ImageSize -> Tiny] & /@ ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{x, y}, {y, x}, {w, x}, {w, z}}, {{0, 0}, {0, 0}}, 10, "StatesList"]
ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{x, y}, {y, x}, {w, x}, {w, z}}, {{0, 0}, {0, 0}}, 13, "FinalStatePlot"]
{{x, y}, {y, z}} -> {{w, y}, {y, z}, {z, w}, {x, w}}
RulePlot[ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{w, y}, {y, z}, {z, w}, {x, w}}]]
ResourceFunction["WolframModelPlot"][#, ImageSize -> Tiny] & /@ ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{w, y}, {y, z}, {z, w}, {x, w}}, {{0, 0}, {0, 0}}, 10, "StatesList"]
ResourceFunction[ "WolframModel"][{{x, y}, {y, z}} -> {{w, y}, {y, z}, {z, w}, {x, w}}, {{0, 0}, {0, 0}}, 14, "FinalStatePlot"]

Much as we have seen in other systems such as cellular automata [1], there seems to be no simple way to deduce from the rules from our systems here what their behavior will be. And indeed even seemingly very similar rules can give dramatically different behavior, sometimes simple, and sometimes complex.